***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul. 31, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD75P04E-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u TC=3m
Rg     g1    g2    3.18
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=210.2  VTO=-2.4  THETA=0  VMAX=5e4  ETA=0  NFS=4.501e11  LEVEL=3  GAMMA=0.65 )
Rd     d1    d2    7.05e-3 TC=4.6m,2u
Dbd    d2    s2    Dbt
.MODEL      Dbt    D(BV=44 TBV1=9.601e-4 TBV2=-9e-7  CJO=6.072e-10   M=5.644e-1   VJ=3.905e-1)
Dbody  21    s2    DBODY
.MODEL DBODY  D(IS=3e-11   N=1.080  RS=4.012e-8  EG=1.1  TT=20n  IKF=4.17 TIKF=9.913e-3)
Rdiode d1    21    2.35e-3  TC=1.9m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a     a    sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.566e-9
.MODEL    DGD    D(CJO=1.566e-9 M=4.33e-1  VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       d2   a   DGD
Rpar2     d2   a    10Meg
Cgs       g2   s2  2.042e-9
.ENDS PJD75P04E-AU
*$
